simulation.hsim

title="FNR regulator simulation";
geometry = 200:50; // size of E.coli in unit of 10nm 200 : 50=2:0.5 µm
//molecules list
molecule Pfnr;//fnr promotor
molecule Ise,ClpXP;//Ise: iron-sulfur cluster assembly proteins : enzyme of dimerisation ; ClpXP: ATP dependent protease that induces degradation for all protein
molecule QFeFNRa,apoFNR,DFeFNRi;//3 states of FNR: activated, without Fe (inactivated), and inactivated
molecule GPV,PV;//GPV green protein gene, PV green protein
molecule GPR,PR;//GPR red protein gene, PR red protein
molecule QFeFNRa_GPR_binded,QFeFNRa_GPV_binded;//molecule FNR binds on mRNA from GPR and GPV
molecule rep;//complexe of 4 FNRs, prevent production of red protein
metabolite o2;//declare the o2 as a cytosolic molecule leads to be treated as an homogeneous population
//size in 10nm unit
size(Pfnr)=0.01;

size(Ise)=0.5; size(ClpXP)=0.5;
size(QFeFNRa)=2;
size(apoFNR)=1;
size(DFeFNRi)=2;
size(GPV)=0.01;
size(PV)=1;
size(GPR)=0.01;
size(PR)=1;
size(QFeFNRa_GPR_binded)=2.01;
size(QFeFNRa_GPV_binded)=2.01;
size(rep)=4.02;
//speed
speed(Pfnr)=0;
speed(Ise)=0.5;
speed(ClpXP)=0.5;
speed(QFeFNRa)=0.3;
speed(DFeFNRi)=0.3;
speed(apoFNR)=0.3;
speed(GPV)=0;
speed(PV)=0.3;
speed(GPR)=0;
speed(PR)=0.3;
speed(QFeFNRa_GPR_binded)=0;
speed(QFeFNRa_GPV_binded)=0;
speed(rep)=0;
//reactions
//translating Pfnr to FNR
Pfnr -> Pfnr + apoFNR [0.1];//fnr mRNA generates steagyly apoFNR(inactived)
//dimerisation
apoFNR + Ise -> QFeFNRa + Ise[0.8];//production of 4Fe-FNR by Ise is steady
//oxydation
QFeFNRa + o2 -> DFeFNRi +o2 [0.8];//aerobically, oxygen inactivates FNR
DFeFNRi + Ise -> QFeFNRa + Ise [0.5];//but cell continues to reactivate it steadly
DFeFNRi + o2 -> apoFNR +o2 [0.6];//return to apoFNR
//degradation FNR
apoFNR + ClpXP -> ClpXP [0.05];
DFeFNRi + ClpXP -> ClpXP [0.05];
QFeFNRa + ClpXP -> ClpXP [0.05];
//activation/inactivation of green gene
QFeFNRa + GPV -> QFeFNRa_GPV_binded [0.8];//association
QFeFNRa_GPV_binded -> QFeFNRa + GPV [0.4];//dissociation
QFeFNRa_GPV_binded -> PV + QFeFNRa_GPV_binded [0.3];//production of green protein
//green protein degradation
PV + ClpXP -> ClpXP [0.05];
//repression of red gene
QFeFNRa + GPR -> QFeFNRa_GPR_binded [0.8];
QFeFNRa_GPR_binded -> QFeFNRa + GPR [0.1];
QFeFNRa_GPR_binded + QFeFNRa_GPR_binded -> rep [0.5];
rep -> QFeFNRa_GPR_binded + QFeFNRa_GPR_binded [0.05];
//expression the red gene in aerobic condition
GPR -> GPR + PR [0.3];//production of red protein
QFeFNRa_GPR_binded -> QFeFNRa_GPR_binded + PR [0.1];
//degradation of red protein
PR + ClpXP -> ClpXP [0.05];
//initialtion
init(100,Pfnr);
init(100,Ise);
init(100,ClpXP);
init(100,QFeFNRa);
init(100,DFeFNRi);
init(100,apoFNR);
init(100,GPV);
init(10,PV);
init(100,GPR);
init(10,PR);
init(10,o2);
init(10,QFeFNRa_GPR_binded);
init(10,QFeFNRa_GPV_binded);
init(10,rep);